Windows batch goto inside FOR loop

batch-file, for-loop, goto, windows

Solution

Try

for /f "skip=1 tokens=1,2,3,4,5,6,* delims=;" %%a in ('findstr /R "^" z:\csp\levantamento\levantamentoNOVO.csv') do (

 set /A HOME=0
 call :cicle "%%a" "%%c"
)

:: what-to-do-after-for goes in here

goto :eof

:cicle
echo HOME%HOME%
echo \\%~2\HKLM\SOFTWARE\ORACLE\HOME%HOME%

reg query \\%~2\HKLM\SOFTWARE\ORACLE\HOME%HOME% /v ORACLE_HOME

if %HOME% leq 3 (
    set /A HOME+=1
    goto cicle
)
echo.

echo Connection to %~1 deleted
goto :eof

Note that now there is a subroutine called `cicle` which is supplied with parameters `"%%a"` and `"%%c"` Within the `cicle` routine, what was `%%a` becomes `%~1` (the first parameter, minus the quotes) and what was `%%c` becomes `%~2` (the second parameter, minus the quotes).

The quotes are only there in case the parameter being passed contains separator characters, which is unlikely in your current case.

see `call /?` from the prompt for docco.

Note also that `set "var=variable"` is used in string assignments to ensure unwanted trailing spaces are not included in the value assigned. The `set /a` syntax does not suffer from this problem, so the rabbit's ears are not necessary.

Problem

Original source

Related problems

• Batch file: GOTO in a FOR loop