function definition macro in clojure

clojure, clojurescript

Solution

(defmacro defn-check [name check-fn args & tail]
  (let [docstring (if (string? (first tail)) (first tail))
        tail (if docstring (next tail) tail)
        params (take-nth 2 args)
        checks (take-nth 2 (next args))
        cf (gensym "cf__")]
    `(let [~cf ~check-fn]
       (defn ~name
         ~@(if docstring [docstring])
          ~(vec params)
         {:pre ~(mapv (fn [p c]
                        `(= (~cf ~p) ~c))
                      params
                      checks)}
         ~@tail))))

This allows you to specify a docstring if you'd like, but not an attribute map (see `(doc defn)`; adding support for that would be straightforward).

Example:

user> (defn-check funky-add odd? [x true y false] "foo" (+ x y))
#'user/funky-add
user> (doc funky-add)
-------------------------
user/funky-add
([x y])
  foo
nil
user> (funky-add 1 2)
3
user> (funky-add 2 1)
AssertionError Assert failed: (clojure.core/= (cf__2268 x) true)  user/eval2269/funky-add--2270 (form-init1446120099766722611.clj:1)

Problem

I'm trying to make a macro that transform this: ``` (defn-check my-checked-function check-function [a A b B] (do-something a b)) ``` into: ``` (defn my-checked-function [a b] {:pre [(= (check-function a) A) (= (check-function b) B)]} (do-something a b)) ``` I'm new to clojure, could anyone show me how to do that?

Original source