Disallow deletion of master branch in git

git, githooks, perl

Solution

Straightforward with a `pre-receive` hook. Assuming you're using a bare central repository, place the following code in `your-repo.git/hooks/pre-receive`, and don't forget to `chmod +x your-repo.git/hooks/pre-receive`.

#! /usr/bin/perl

# create: 00000... 51b8d... refs/heads/topic/gbacon
# delete: 51b8d... 00000... refs/heads/topic/gbacon
# update: 51b8d... d5e14... refs/heads/topic/gbacon

my $errors = 0;

while (<>) {
  chomp;

  next
    unless m[ ^
              ([0-9a-f]+)       # old SHA-1
              \s+
              ([0-9a-f]+)       # new SHA-1
              \s+
              refs/heads/(\S+)  # ref
              \s*
              $
            ]x;

  my($old,$new,$ref) = ($1,$2,$3);

  next unless $ref =~ /^(master|alpha|beta)$/;

  die "$0: deleting $ref not permitted!\n"
    if $new =~ /^0+$/;
}

exit $errors == 0 ? 0 : 1;

Problem

I’m trying to setup a git hook that will disallow anyone to delete the `master`, `alpha`, and `beta` branches of our repository. Can anyone help with this? I have never done a git hook, so I don’t want to try my luck in developing my own without a little help.

Original source