How do you display an XMPP (Jabber) vcard photo in Delphi?

delphi, vcf-vcard, xml, xmpp

Solution

The XML you posted does not contain the picture. It contains the SHA-1 hash of the picture's contents. You only get the hash, initially, in case you have already fetched that image once before, so you can display the cached version instead of requesting it anew.

If you don't have an image with that hash, then request a new vcard. When it arrives, read the `PHOTO` element, if it's available. It may have two subelements, `BINVAL` and `TYPE`. `BINVAL` will contain the Base-64-encoded version of the image, and `TYPE` will contain the MIME type identifier for the image type, such as image/jpeg or image/png.

Decode the binary data and store it in a stream, such as `TFileStream` or `TMemoryStream`. Next, choose which `TGraphic` descendant is appropriate for the kind of image you have. It might be `TPngImage`, or it might be `TBitmap`. Instantiate the class, and tell it to load the stream's contents. It would go something like this:

function CreateGraphicFromVCardPhoto(const BinVal, MimeType: string): TGraphic;
var
  Stream: TStream;
  GraphicClass: TGraphicClass;
begin
  Stream := TMemoryStream.Create;
  try
    if not Base64Decode(BinVal, Stream) then
      raise EBase64Decode.Create;
    Stream.Position := 0;
    GraphicClass := ChooseGraphicClass(MimeType);
    Result := GraphicClass.Create;
    try
      Result.LoadFromStream(Stream);
    except
      Result.Free;
      raise;
    end;
  finally
    Stream.Free;
  end;
end;

The code above uses the `Base64Decode` function from OmniXML, described in the answer to Saving a Base64 string to disk as a binary using Delphi 2007. Once you have the `TGraphic` value, you can assign it to a `TImage` or do whatever else you can do with `TGraphic`s.

The `ChooseGraphicClass` function might work like this:

function ChooseGraphicClass(const MimeType: string): TGraphicClass;
begin
  if MimeType = 'image/bmp' then
    Result := TBitmap
  else if MimeType = 'image/png' then
    Result := TPngImage
  else if MimeType = 'image/gif' then
    Result := TGifImage
  else if MimeType = 'image/jpeg' then
    Result := TJpegImage
  else
    raise EUnknownGraphicFormat.Create(MimeType);
end;

Problem

Original source

Related problems

• Delphi: How to calculate the SHA hash of a large file