What is the difference between package, module and class in object oriented Perl?

module, oop, perl

Solution

Modules are a single file, a .pm file that provides code. That could be no packages, a single package, or more than one package. A module doesn't really care what is in it, so it can be code that inserts itself into the same namespace, a more-traditional set of subroutines in a library or define Perl's idea of a class.

A package, also known as a namespace, contains its own variables and subroutines. It's a way of segregating different parts of your program. You create the package and put your code into it:

package SomePackage;

sub some_subroutine { ... } # really SomePackage::some_subroutine

You load the module to get access to the package:

use SomePackage; # read and compile the module file

SomePackage::some_subroutine( ... );

A Perl class is a package and its associated behavior. The methods in a class are just normal subroutines, although when we treat the subroutines as methods, the first parameter is the thing (a package name or object, also known as the referent) that called method:

package SomeClass;

sub class_method { my( $class, @args ) = @_; ... }
sub instance_method { my( $self, @args ) = @_; ... }

Since the class is just a package like any other package and probably lives in a module, you access it the same way with `use`:

 use SomeClass;

 my $i = SomeClass->class_method( ... ); 

The OO arrow syntax does some special stuff to let the `some_method` subroutine know that it's being called as a method. Perl puts the referent (the `SomeClass` in this case) as the first argument. Additionally, when using the OO syntax, Perl knows to use its inheritance features.

Methods called with '->' get the referent as the first parameter to the method, so this call:

  SomeClass->new('world'); 

is syntactically the same as if you had called it with the class name as the first parameter:

  SomeClass::new( 'SomeClass' ,'world'); # no inheritance this way

That works the same for objects too. When an object is the referent:

my $i = SomeClass->new(); 
$i->bar( 'world'); 

the object is the first parameter as the method:

SomeClass::bar($i, 'world'); 

Problem

Original source