How do pass one array and one string as arguments to a function?

arrays, function, parameters, perl, string

Solution

You can't pass arrays to subs, only lists of scalars.

ifin(@f, $k);

is the same as

ifin($f[0], $f[1], $f[2], $f[3], $k);

because `@f` evaluates to a list of its elements.

One way of passing an array to a sub is to pass a reference.

sub ifin {
   my ($array, $str) = @_;
   for my $e (@$array) {
      return 1 if $e eq $str;
   }

   return 0;
}

my @f = (1,2,3,4);
my $k = 1;
print(ifin(\@f, $k), "\n");

By the way, that can also be written as:

my @f = (1,2,3,4);
my $k = 1;
print(( grep { $_ eq $k } @f ) ? 1 : 0, "\n");

You could keep the existing calling convention by using `pop`.

sub ifin {
   my $str = pop(@_);
   for my $e (@_) {
      return 1 if $e eq $str;
   }

   return 0;
}

my @f = (1,2,3,4);
my $k = 1;
print(ifin(@f, $k), "\n");

Problem

Original source

Related problems

• How can I verify that a value is present in an array (list) in Perl?
• Faster way to check for element in array?