What is the fastest solution to compare JPEG image? (ignoring metadata, just the "pixels")

comparison, delphi, jpeg

Solution

JPEG file consists of chunks, which types are identified by markers. The structure of chunks (except for stand-alone SOI, EOI, RSTn):

chunk type marker (big-endian FFxx)
chunk length (big-endian word)
data (length-2 bytes)

Edit: SOS chunk is limited by another marker, not by length.

Metadata chunks start with APPn marker (FFEn), except for APP0 (FFE0) marker with JFIF title.

So we can read and compare only significant chunks and ignore APPn chunks and COM chunk (as TLama noticed).

Example: hex view of some jpeg file:

It starts with SOI (Start Of Image) marker FFD8 (stand-alone, without length),

then APP0 chunk (FFE0) with length = 16 bytes,

then APP1 chunk (FFE1), which contains metadata (EXIF data, NIKON COOLPIX name etc), so we can ignore 9053 bytes (23 5D) and check next chunk marker at address 2373, and so on...

Edit: Simple parsing example:

var
  jp: TMemoryStream;
  Marker, Len: Word;
  Position: Integer;
  PBA: PByteArray;

  procedure ReadLenAndMovePosition;
  begin
    Inc(Position, 2);
    Len := Swap(PWord(@PBA[Position])^);
    Inc(Position, Len);
  end;

begin
  jp := TMemoryStream.Create;
  jp.LoadFromFile('D:\3.jpg');
  Position := 0;
  PBA := jp.Memory;

  while (Position < jp.Size - 1) do begin
    Marker := Swap(PWord(@PBA[Position])^);
    case Marker of
      $FFD8: begin
          Memo1.Lines.Add('Start Of Image');
          Inc(Position, 2);
        end;
      $FFD9: begin
          Memo1.Lines.Add('End Of Image');
          Inc(Position, 2);
        end;
      $FFE0: begin
          ReadLenAndMovePosition;
          Memo1.Lines.Add(Format('JFIF Header Len: %d', [Len]));
        end;
      $FFE1..$FFEF, $FFFE: begin
          ReadLenAndMovePosition;
          Memo1.Lines.Add(Format('APPn or COM Len: %d Ignored', [Len]));
        end;
      $FFDA: begin
          //SOS marker, data stream, ended by another marker except for RSTn
          Memo1.Lines.Add(Format('SOS data stream started at %d', [Position]));
          Inc(Position, 2);
          while Position < jp.Size - 1 do begin
            if PBA[Position] = $FF then
              if not (PBA[Position + 1] in [0, $D0..$D7]) then begin
                Inc(Position, 2);
                Memo1.Lines.Add(Format('SOS data stream ended at %d',
                  [Position]));
                Break;
              end;
            Inc(Position);
          end;
        end;
    else begin
        ReadLenAndMovePosition;
        Memo1.Lines.Add(Format('Marker %x Len: %d Significant', [Marker, Len]));
      end;
    end;
  end;
  jp.Free;
end;

Problem

Original source

Related problems

• Delphi function comparing content of two TStream?